PDF statt Firmenpapier

Wie oft drucken wir ein Dokument auf Firmenpapier aus und scannen es wieder ein, damit es elektronisch gleich aussieht, wie der Druck auf Firmenpapier? Jedes Mal ist das gescannte Resultat eine Enttäuschung. Grafische Elemente des Firmenlayouts verlieren an Farbe und Qualität. Kurz - der Empfänger sieht, dass es gescannt wurde. Vermeiden Sie diesen Umweg über Papierform und verwenden Sie eine PDF-Vorlage als Briefpapier.

Mit dem Redesign des CI/CD der AS infotrack haben wir die Layouts unserer Dokumente überarbeitet. Eingeflossen sind alle modernen stilistischen Elemente, welche ein frisches und einladendes Dokument definieren.

Für das Backoffice haben wir die Office-Vorlagen erstellt. Wir haben bewusst darauf verzichtet, die grafischen Elemente des CI/CD in die Vorlagen einzuarbeiten. Das heisst, dass jedes für externe Empfänger bestimmte Dokument auf vorgedrucktes Firmenpapier gedruckt wird.

Will man nun ein solches Dokument elektronisch verteilen, führte der Weg über das Scannen des gedruckten Dokuments – natürlich mit entsprechendem Qualitätsverlust.

Für den Versand per eMail suchten wir nach einer anderen Lösung. Ist es möglich auf einen PDF-Printer zu drucken und gleichzeitig das richtige Layout hinzuzufügen? Nach langem Suchen sind wir auf die Lösung gestossen. In diesem Blog-Beitrag erfahren Sie, wie Sie Ihren elektronischen Dokumenten Ihr Firmenpapier über den PDF-Drucker hinzufügen.



1.Anforderung

Damit aus einem beliebigen Office-Programm ein PDF-Dokument generiert werden kann, brauchen Sie ein Tool, welches den Druckprozess in ein PDF-Dokument umleitet und dieses als PDF-Dokument abspeichert. Die handelsüblichen Office-Pakete bieten direkt die Möglichkeit ein erstelltes Dokument als PDF zu speichern. So können wir aber noch nicht das Firmen-Template dazu generieren. Für unseren Lösungsweg benötigen Sie:

Zudem muss das Briefpapier als PDF-Datei existieren. Hier macht es Sinn für jeden Verwendungszweck eine eigene Datei zu erzeugen. Zum Beispiel für den Firmenbrief, die Dokumentation und die Rechnung. Die Vorlagen dürfen auch mehrseitig sein. Die erste Seite ist meistens das Deckblatt und die weitere Seiten mit der Kopf- und Fusszeile und dem entsprechenden CI/CD.

2.Technische Umsetzung

Installieren der Software

Über die obenstehenden Links können Sie die benötigten Programme herunterladen. Sowohl bei dem PDFCreator als auch beim PDF Toolkit können Sie mit der minimalsten Installationsoption alle notwendigen Komponenten auf Ihrem System installieren. Damit Sie die beiden Programme und die nachfolgenden Schritte auch fehlerfrei ausführen können, benötigen Sie auf ihrem PC lokale Administrator-Rechte.

Skript anpassen

Im Verzeichnis ...\PDFCreator\Scripts\RunProgramAfterSaving befinden sich nach der Installation Beispiel-Skripte für verschiedenste Zwecke. Wir benötigen für unsere Aufgabe das Skript AddWatermarkToPDF.vbs. Kopieren Sie dieses Skript und geben Sie diesem einen Namen. Für uns ist ASi_Documentation.vbs die adäquate Bezeichnung. Kopieren Sie das PDF-Template ebenfalls in dieses Verzeichnis. Hier haben wir unsere Vorlage ASi_Docu.pdf benannt.

Das kopierte Skript passen wir nach unseren Bedürfnissen und auf unsere Systemumgebung an. Wichtig ist hier, dass die als Konstanten deklarierten Variablen korrekt gesetzt werden. Je nach System müssen Sie die Werte für die Variable PathToPdftk und WatermarkPDF korrekt setzen.

Const PathToPdftk = "C:\Program Files (x86)\PDFtk\bin\pdftk.exe"
Const WatermarkPDF = "C:\Program Files (x86)\PDFCreator\Scripts\RunProgramAfterSaving\ASi_Docu.pdf"

Diese Werte werden weiter unten im Skript wieder an den notwendigen Stellen eingesetzt. Achtung: Ein Stolperstein sind alle Leerschläge in Ihrem Pfad und Dokumentennamen. Die nachfolgende Zeile ist deshalb korrekt mit "" zu codieren, damit das Skript fehlerfrei ausgeführt wird.

So funktionierte es bei uns:

WshShell.Run """" &PathToPdftk & """" & " """ & fname & """ multibackground """ & WatermarkPDF & """ output """ & tfname & """",0,true

Nachfolgend das gesamte Script:

' AddWatermarkToPDF script
' Part of PDFCreator
' License: GPL
' Homepage: http://www.sf.net/projects/pdfcreator
' Version: 1.1.0.0
' Date: September, 1. 2005
' Author: Frank Heindörfer
' Comments: This script needs pdftk.
'           For more informations about the freeware pdftk use this link:
'           http://www.accesspdf.com
'
' Date: November, 30. 2013
' Copied and modified by AS infotrack AG for printing dokuments with CI template

Option Explicit

Const AppTitle = "PDFCreator - AddWatermarkToPDF"
Const PathToPdftk = "C:\Program Files (x86)\PDFtk\bin\pdftk.exe"
Const WatermarkPDF = "C:\Program Files (x86)\PDFCreator\Scripts\RunProgramAfterSaving\ASi_Docu.pdf"

Dim objArgs, fname, tfname, fso, WshShell, oExec

Set objArgs = WScript.Arguments

If objArgs.Count = 0 Then
	MsgBox "This script needs a parameter!", vbExclamation, AppTitle
	WScript.Quit
End If

fname = objArgs(0)

Set fso = CreateObject("Scripting.FileSystemObject")

If Ucase(fso.GetExtensionName(fname)) <> "PDF" Then
	MsgBox "This script works only with pdf files!", vbExclamation, AppTitle
	WScript.Quit
End If

If Not fso.FileExists(PathToPdftk) Then
	MsgBox "You need pdftk for this script!" & vbcrlf & vbcrlf & _
		"Please go to http://www.accesspdf.com and download it.", vbExclamation, AppTitle
	WScript.Quit
End If

If Not fso.FileExists(WatermarkPDF) Then
	MsgBox "Can't find the watermark pdf file!", vbExclamation, AppTitle
	WScript.Quit
End If

Set WshShell = CreateObject("WScript.Shell")

tfname = fso.GetTempName
WshShell.Run """" &PathToPdftk & """" & " """ & fname & """ multibackground """ & WatermarkPDF & """ output """ & tfname & """",0,true

If Not fso.FileExists(tfname) Then
	MsgBox "There was an error using ""pdftk""!", vbCritical, AppTitle
	WScript.Quit
End If

If fso.FileExists(fname) Then
	fso.DeleteFile(fname)
End If

fso.MoveFile tfname, fname

Nun sollte alles passen, und wir können die letzte notwendige Einstellung vornehmen.

PDFCreator konfigurieren

Dazu starten wir den PDFCreator und rufen die Einstellungen auf. Als erstes erzeugen wir ein neues, eigenes Profil. Wählen Sie den Namen, welcher Ihren Zweck am besten beschreibt. Wir haben hier ASi_Documentation_Template gewählt.

Unter Programm/Aktionen halten wir fest, welches Skript der PDFCreator nach dem Erstellen und Speichern des Dokuments ausführen soll. Dieses Skript befindet sich im Installationsverzeichnis des PDFCreator im Ordner …\PDFCreator\Scripts\RunProgramAfterSaving. In unserem Fall heisst das Skript ASi_Documentation.vbs.

Der vollständige Pfad zum Script lautet: C:\Program Files (x86)\PDFCreator\Scripts\RunProgramAfterSaving\ASi_Documentation.vbs. Alle weiteren Einstellungen können Sie nach Ihren Bedürfnissen hier vornehmen. Wichtig ist, dass Sie nicht vergessen zu speichern.

3.Fertige Lösung

Wenn Sie Ihr Dokument fertig erstellt haben, können Sie dieses über den Druckprozess mit dem vorbereiteten PDF-Template zusammenführen. Wählen Sie als Drucker PDFCreator und im angezeigten Dialog Ihr Profil für das Template aus. Der PDFCreator ruft nach dem Generieren des Originaldokumentes das eingebettete Skript auf. Dieses packt das Originaldokument und die Vorlage zusammen und generiert das gewünschte Dokument mit Ihrem Briefpapier-Layout.

Ob Sie das Dokument in ein Verzeichnis speichern oder direkt an einen eMail-Empfänger senden wollen, spielt dabei keine Rolle.


Daniel Kleiner

Bereichsleiter Solutions


Bei meiner Arbeit schreibe ich viele Dokumentationen für die entwickelten Softwarelösungen und für neu definierte Abläufe. Der Inhalt ist dabei das Wichtigste. Mir gefällt es jedoch viel besser, wenn auch das fertige Dokument in seiner ganzen Erscheinung perfekt daher kommt. Mit dieser Lösung kann ich nun vom Schreiben bis zum Finish des Dokuments alles abschliessen. Das generierte PDF-Dokument verteile ich so viel lieber an die Empfänger.